I’ll help, but in a totally different way than you would expect.
Your code is, honestly, a mess. You have if statements all over the place, empty else statements, and I can’t understand the logic at all.
Let’s start over. First, we want to start with an empty sketch. But that alone is boring, so let’s think about what things there are in a game of Pong. Traditionally, Pong has a Ball and two Paddles. To keep things tidy, we’ll make a couple of classes for these things. That way we can encapsulate their logic properly.
class Ball {
Ball() {
}
}
class Paddle {
Paddle() {
}
}
void setup() {
size(600, 400);
}
void draw() {
background(0);
}
Of course, nothing happens in this sketch so far. We need to add some logic to draw the Ball and paddles, and create a couple of these objects too! We can add this logic to the classes, and draw these objects in draw().
class Ball {
float x, y, v, dx, dy;
int s;
Ball() {
x = width/2;
y = height/2;
v = 5;
s = 20;
float a = random(TWO_PI);
dx = v * cos(a);
dy = v * sin(a);
}
void draw() {
move();
ellipse(x, y, s, s);
}
void move() {
x += dx;
y += dy;
}
}
class Paddle {
float x, y;
Paddle(boolean onLeft) {
x = 20;
if ( onLeft ) {
x = width-20;
}
y = height/2;
}
void draw() {
rect(x-10, y-50, 20, 100);
}
}
Paddle paddleL, paddleR;
Ball ball;
void setup() {
size(600, 400);
// Create paddles.
paddleL = new Paddle(true);
paddleR = new Paddle(false);
// Create ball.
ball = new Ball();
}
void draw() {
background(0);
// Draw paddles.
paddleL.draw();
paddleR.draw();
// Draw ball.
ball.draw();
}
This already looks like a pong game! And, well, it should, because it’s doing all the drawing of the objects in the game.
But some logic is still missing. For one, the Ball doesn’t care about flying of the top or bottom. It also needs to bounce off the panels, and needs to reset if it flies off the left or right sides. We need the paddles to move as well. We also need some logic to track and possibly display the score.
Let’s try adding some of that now.
class Score {
int player, computer;
Score(){
player = 0;
computer = 0;
}
void player_point(){
player++;
}
void computer_point(){
computer++;
}
void draw(){
text("" + player + " - " + computer, width/2, 30);
}
}
class Ball {
float x, y, v, dx, dy;
int s;
Ball() {
v = 5;
s = 20;
reset();
}
void reset(){
x = width/2;
y = height/2;
float a = random(TWO_PI);
dx = v * cos(a);
dy = v * sin(a);
// Avoid "stalemate".
if( abs(dx) < 0.1 ){
reset();
}
}
void draw() {
move();
ellipse(x, y, s, s);
}
void move() {
x += dx;
y += dy;
// Bounce off top and bottom.
if( y < s/2.0){
dy *= -1;
y = s/2.0;
}
if( y > height - s/2.0){
dy *= -1;
y = height - s/2.0;
}
// Detect off left or right side.
if( x < -10 ){
score.computer_point();
reset();
}
if( x > width + 10 ){
score.player_point();
reset();
}
}
}
class Paddle {
float x, y;
boolean onLeft;
Paddle(boolean _onLeft) {
onLeft = _onLeft;
x = 20;
if ( !onLeft ) {
x = width-20;
}
y = height/2;
}
void draw() {
move();
rect(x-10, y-50, 20, 100);
}
void move() {
if (onLeft) { // Player-controlled paddle.
if ( keyUp && !keyDown ) {
y--;
}
if ( keyDown && !keyUp ) {
y++;
}
} else { // Computer-controlled paddle.
if ( ball.y > y ) {
y++;
} else {
y--;
}
}
// Limit paddle movements for both paddles.
if (y < 50) {
y = 50;
}
if (y > height-50) {
y = height-50;
}
}
}
Paddle paddleL, paddleR;
Ball ball;
Score score;
// Global key state tracking for the left paddle.
boolean keyUp, keyDown;
void setup() {
size(600, 400);
noStroke();
textSize(32);
textAlign(CENTER);
// Create paddles.
paddleL = new Paddle(true);
paddleR = new Paddle(false);
// Create ball.
ball = new Ball();
// Create scoreboard.
score = new Score();
}
void draw() {
background(0);
// Draw paddles.
paddleL.draw();
paddleR.draw();
// Draw ball.
ball.draw();
// Draw scoreboard.
score.draw();
}
// Code to deal with key pressing.
void keyHandle(boolean b) {
if ( keyCode == UP ) {
keyUp = b;
}
if ( keyCode == DOWN ) {
keyDown = b;
}
}
void keyPressed() {
keyHandle(true);
}
void keyReleased() {
keyHandle(false);
}
Well, it mostly works. The ball just needs to bounce off the paddles now.
I’ll leave adding that logic as an exercise for you. Notice that you can see clearly where this logic should be added! That’s because the code is structured in a way that makes sense…
