here…
// for explosions (these are actually Shrapnels)
ArrayList <Explosion> missiles;
//
// ---------------------------------------------------------------
//
void setup() {
// runs only once - init
size(800, 600);
// explosions --------------------------------------
// Create an empty ArrayList
missiles = new ArrayList<Explosion>();
//
} // func
void draw() {
// runs again and again
// delete screen
background(0, 64, 0);
// explosions (show moving shrapnels)
explosionManager();
} // func
//------------------------------------------------------------------------
void mousePressed() {
explode(); // Init new explosion!!!!
}
void explode() {
// Init new explosion!!!!
// explode!
missiles.clear();
int maxMissiles = int(random(4, 222));
for (int i=0; i<maxMissiles; i++) {
// this is where explode missile/shrapnel object is created
// and added to the missiles arrayList.
// It is small (4) and life decrease is .72 (how fast it dies),
// no Line (false).
missiles.add(
new Explosion(
random(mouseX-3, mouseX+3), random(mouseY-9, mouseY+9), // POS:
random(-1.3, 1.3), random(-2.7, .6),
4, .72, false)); //
}
} // method
//--------------------------------------------------------------------------------------------------
// the tab for Explosions and related and the complete class
void explosionManager() {
// this is a new for loop.
// Actually for the Shrapnels.
for (Explosion m : missiles) {
m.decreaseLife(); // call the decrease life (for explosion)
m.fly(); // call the "fly" method of the missile
m.display(); // call the "display" method of the missile
}
//
// remove dead ones (you need to have a conventional for-loop here)
for (int i=missiles.size()-1; i>=0; i--) {
Explosion m = (Explosion) missiles.get(i);
if (m.dead) {
missiles.remove(i);
}
}
} // func
// ===============================================================
class Explosion {
// ONE shrapnel
float startlocX, startlocY; // start pos
float x, y; // current pos
float xvel, yvel; // velocity
float sizeMissile ; // size for rect
float life=20; // how much lifes does it have
float lifeDecrease; // remove lifes
boolean dead=false; // is it alive?
boolean withLine; // draw line? Explosion has none.
//
// contructor
Explosion(
float _startlocX, float _startlocY,
float _xvel, float _yvel,
float _size, float _lifeDecrease,
boolean _withLine)
{
startlocX = _startlocX;
startlocY = _startlocY;
x = startlocX;
y = _startlocY;
sizeMissile = _size;
lifeDecrease=_lifeDecrease;
xvel = _xvel;
yvel = _yvel;
withLine=_withLine;
} // contructor
//
void display() {
//stroke(255, 2, 2);
fill(255, 2, 2);
noStroke();
if (withLine) {
line(startlocX, startlocY, x, y);
}
sizeMissile-=.07;
rect(x, y, sizeMissile, sizeMissile);
} // method
//
void fly() {
x += xvel;
y += yvel;
} // method
//
void decreaseLife() {
life-=lifeDecrease;
if (life<=0 || sizeMissile<=0) {
dead=true;
}
} // method
//
} // class
//
// ======================================================================
